Création et paramétrage dynamique de requêtes

Date de publication : 19/05/2005

Par Christophe WARIN
 

Ce tutoriel est destiné aux lecteurs souhaitant créer dynamiquement des requêtes paramétrables et ainsi, améliorer leurs systèmes de sélection de critères dans des requêtes Microsoft Access.

1. Introduction

La table utilisée en guise d'exemple est issue de la base de données Comptoir.mdb disponible dans le répertoire Samples d'Office

2. Pourquoi un tel besoin ?

SELECT * FROM Clients
WHERE Code_Client=[Sélectionnez un numéro de client];

3. Principe de réalisation

4. Création de la requête modèle

SELECT * FROM Clients
WHERE Pays=[CriterePays];

5. Création du formulaire

SELECT DISTINCT Pays FROM Clients ORDER BY Pays

6. Création de la nouvelle requête

6.1. Déclaration de la référence DAO

6.2. Détails du fonctionnement

6.3. Comment tester si une requête existe déjà

Public Function TesteExistenceRequete(strNomRequete As String) As Boolean
On Error GoTo err
Dim Db As DAO.Database
Dim QryTest As DAO.QueryDef
'initialise un objet représentant la base de données
Set Db = CurrentDb
'tente d'accéder à la requête
Set QryTest = Db.QueryDefs(strNomRequete)
TesteExistenceRequete = True
err:
End Function

6.4. Modification de la requête modèle

Dim Db As DAO.Database
Dim QryModele As DAO.QueryDef
Dim strSQLModele As String
Set Db = CurrentDb
Set QryModele = Db.QueryDefs("qryClientParPays_modele")
strSQLModele = QryModele.SQL

SELECT * FROM Clients
WHERE Pays="FRANCE";

SELECT * FROM Clients
WHERE DateNaissance=#10/22/1976#

strSQLModele = Replace(strSQLModele, "[criterepays]", Chr(34) & Nz(cboPays) & Chr(34))

6.5. Sauvegarde de la nouvelle requête

'Si la requête existe déjà alors
If TesteExistenceRequete("qryClientParPays") Then
  'alors modifier le code de la requête
  Db.QueryDefs("qryClientParPays").SQL = strSQLModele
'Sinon
Else
  'Créer la nouvelle requête
  Db.CreateQueryDef "qryClientParPays", strSQLModele
End If

6.6. Affichage des données

DoCmd.OpenQuery "qryClientParPays"

Private Sub btValider_Click()
Dim Db As DAO.Database
Dim QryModele As DAO.QueryDef
Dim strSQLModele As String
Set Db = CurrentDb
Set QryModele = Db.QueryDefs("qryClientParPays_modele")
strSQLModele = QryModele.SQL
'Effectue le remplacement du critere par la valeur
strSQLModele = Replace(strSQLModele, "[criterepays]", Chr(34) & Nz(cboPays) & Chr(34))
'Si la requête existe déjà alors
If TesteExistenceRequete("qryClientParPays") Then
  'alors modifier le code de la requête
  Db.QueryDefs("qryClientParPays").SQL = strSQLModele
'Sinon
Else
  'Créer la nouvelle requête
  Db.CreateQueryDef "qryClientParPays", strSQLModele
End If
'Ouvre la requête
DoCmd.OpenQuery "qryClientParPays"
'Ferme le formulaire
DoCmd.Close acForm, Me.Name
End Sub

Private Sub btValider_Click()
On Error GoTo err
Dim Db As DAO.Database
Dim QryModele As DAO.QueryDef
Dim strSQLModele As String
Set Db = CurrentDb
Set QryModele = Db.QueryDefs("qryClientParPays_modele")
strSQLModele = QryModele.SQL
'Effectue le remplacement du critere par la valeur
strSQLModele = Replace(strSQLModele, "[criterepays]", Chr(34) & Nz(cboPays) & Chr(34))
'Si la requête existe déjà alors
If TesteExistenceRequete("qryClientParPays") Then
  'alors modifier le code de la requête
  Db.QueryDefs("qryClientParPays").SQL = strSQLModele
'Sinon
Else
  'Créer la nouvelle requête
  Db.CreateQueryDef "qryClientParPays", strSQLModele
End If
DoCmd.OpenQuery "qryClientParPays"
'Ferme le formulaire
DoCmd.Close acForm, Me.Name
Exit Sub
err:
MsgBox "Une erreur est survenue", vbCritical, "Sélection d'un client"
End Sub

Private Sub btValider_Click()
On Error GoTo err
Dim Db As DAO.Database
Dim QryModele As DAO.QueryDef
Dim strSQLModele As String
Dim strNomQueryModele As String
Dim strNomQuery As String
strNomQueryModele = "qryClientParPays_modele"
strNomQuery = "qryClientParPays"
Set Db = CurrentDb
Set QryModele = Db.QueryDefs(strNomQueryModele)
strSQLModele = QryModele.SQL
'Effectue le remplacement du critere par la valeur
strSQLModele = Replace(strSQLModele, "[criterepays]", Chr(34) & Nz(cboPays) & Chr(34))
'Si la requête existe déjà alors
If TesteExistenceRequete(strNomQuery) Then
  'alors modifier le code de la requête
  Db.QueryDefs(strNomQuery).SQL = strSQLModele
'Sinon
Else
  'Créer la nouvelle requête
  Db.CreateQueryDef strNomQuery, strSQLModele
End If
DoCmd.OpenQuery strNomQuery
'Ferme le formulaire
DoCmd.Close acForm, Me.Name
Exit Sub
err:
MsgBox "Une erreur est survenue", vbCritical, "Sélection d'un client"
End Sub

7. Visualisation

8. Aller plus loin ...

Dans le cas où vous auriez à stocker de grandes requêtes, vous pouvez utiliser le type Mémo pour le champ CodeRqt.

8.1. Code du bouton Valider

Private Sub btValider_Click()
On Error GoTo err
Dim Db As DAO.Database
Dim QryModele As DAO.QueryDef
Dim RstTable As DAO.Recordset
Dim strSQLModele As String
Dim strNomRqt As String
'Instancie la base de données
Set Db = CurrentDb
'Ouvre la table des requetes sur l'enregistrement
'dont le nom de la requête est "qryClientParPays"
strNomRqt = "qryClientParPays"
Set RstTable = Db.OpenRecordset("SELECT * FROM tblRequete WHERE NomRqt=" & Chr(34) & strNomRqt & Chr(34))
'Si la requête est trouvée dans la table,
If Not RstTable.EOF Then
  'Récupère le code correspondant
  strSQLModele = RstTable.Fields("CodeRqt")
  'Effectue le remplacement du critere par la valeur
  strSQLModele = Replace(strSQLModele, "[criterepays]", Chr(34) & Nz(cboPays) & Chr(34))
  'Si un objet requête existe déjà alors
  If TesteExistenceRequete(strNomRqt) Then
    'alors modifier le code de la requête
    Db.QueryDefs(strNomRqt).SQL = strSQLModele
    'Sinon
  Else
    'Créer la nouvelle requête
    Db.CreateQueryDef strNomRqt, strSQLModele
  End If
  DoCmd.OpenQuery "qryClientParPays"
  'Ferme le formulaire
  DoCmd.Close acForm, Me.Name
'Sinon
Else
'Avertir que le code SQL n'est pas disponible
MsgBox "Impossible de trouver la requête : " & strNomRqt & " dans la table des requêtes"
End If

Exit Sub
err:
MsgBox "Une erreur est survenue" & vbCrLf & err.Description, vbCritical, "Sélection d'un client"
End Sub

Vous trouverez un cours complet sur l'accès aux données via DAO à l'adresse suivante : http://warin.developpez.com/TutorielDAO

8.2. Exemple d'utilisation

9. Conclusion